$!-----------------------------------------------------------------------------
$! BUILD_QUERY.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 04-OCT-1998  MGD  remove MapUrl link,
$!                   consolidate Extract here
$! 25-MAY-1998  MGD  merged source files
$! 01-DEC-1995  MGD  VAX migrate from VAX C to DEC C
$! 25-MAY-1995  MGD  added AXP build
$! 05-DEC-1994  MGD  initial development
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ @WASD_ROOT:[SRC]ARCHER.COM "QUERY"
$!
$!(assume CGILIB #include is in same directory except for WASD)
$ INCLUDES = " /INCLUDE=([SRC.MISC])"
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC,ADDRCONSTEXT))"
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='WASD_OBJ_DIR' QUERY
$    CC 'CC_OPTIONS' /OBJECT='WASD_OBJ_DIR' EXTRACT
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    CGILIB_OLB = "[SRC.MISC.OBJ_''WASD_ARCH_NAME']CGILIB.OLB"
$    LINK /EXECUTABLE=WASD_EXE:QUERY.EXE -
     'WASD_OBJ_DIR'QUERY,'CGILIB_OLB'/LIBRARY
$    LINK /EXECUTABLE=WASD_EXE:EXTRACT.EXE -
     'WASD_OBJ_DIR'EXTRACT,'CGILIB_OLB'/LIBRARY
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'WASD_OBJ_DIR'
$!
$!-----------------------------------------------------------------------------