$! CGI_SYMBOLS.COM
$! (shows more detailed information if made subject to authorization)
$!
$ write sys$output "Content-Type: text/plain"
$ write sys$output "Script-Control: X-buffer-records"
$ write sys$output ""
$!
$ SysNet = f$trnlnm("SYS$NET")
$ if SysNet .nes. "" .and. f$extract(0,4,SysNet) .nes. "_MBA" 
$    then DECnet = 1
$    else DECnet = 0
$ endif
$!
$ if DECnet
$ then
$    write sys$output f$fao("!17*-!/DECnet CGI script!/!17*-!/") 
$ else
$    if f$getjpi("","master_pid") .eqs. f$getjpi("","pid")
$       then write sys$output f$fao("!27*-!/Detached process CGI script!/!27*-!/") 
$       else write sys$output f$fao("!21*-!/Subprocess CGI script!/!21*-!/") 
$    endif
$ endif
$!
$ remuser = ""
$ if f$type(www_server_software) .nes. ""
$ then
$    if f$type(www_remote_user) .nes. "" then remuser = www_remote_user
$ else
$    if f$type(remote_user) .nes. "" then remuser = remote_user
$ endif
$ if remuser .eqs. ""
$ then
$!   (not subject to authorization)
$    delete /symbol remuser
$    write sys$output ""
$    if f$type(www_server_software) .nes. ""
$       then show symbol www_*
$       else show symbol *
$    endif
$    if DECnet
$    then
$       write sys$output f$fao("!/!34*-!/How do we know it's really DECnet?!/!34*-!/!/") 
$       show logical /process sys$output
$    endif
$ else
$!   (subject to authorization)
$    delete /symbol remuser
$    show process 
$    write sys$output f$fao("!/!11*-!/CGI symbols!/!11*-!/!/") 
$    if f$type(www_server_software) .nes. ""
$       then show symbol www_*
$       else show symbol *
$    endif
$    if f$type(www_server_software) .nes. ""
$    then
$       write sys$output f$fao("!/!15*-!/All DCL symbols!/!15*-!/!/") 
$       show symbol *
$    endif
$    if DECnet
$    then
$       write sys$output f$fao("!/!34*-!/How do we know it's really DECnet?!/!34*-!/!/") 
$       show logical /process sys$output
$       show logical /job sys$rem_*
$    endif
$ endif