$!-----------------------------------------------------------------------------
$! BUILD_FETCH.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 28-OCT-2000  MGD  use CGILIB object library
$! 30-OCT-1999  MGD  remove NETLIB support
$! 30-MAY-1998  MGD  initial re-development
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ @WASD_ROOT:[SRC]ARCHER.COM "FETCH"
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$ INCLUDES = " /INCLUDE=[SRC.MISC]"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC,ADDRCONSTEXT))"
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='WASD_OBJ_DIR' FETCH
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$!   (default for UCX)
$    IF F$TRNLNM("UCX$IPC_SHR") .EQS. "" -
        THEN DEFINE /USER UCX$IPC_SHR SYS$SHARE:UCX$IPC_SHR.EXE
$    CGILIB_OLB = "[SRC.MISC.OBJ_''WASD_ARCH_NAME']CGILIB.OLB"
$    SET NOON
$    SET VERIFY
$    LINK /EXECUTABLE=WASD_EXE:FETCH.EXE -
     'WASD_OBJ_DIR'FETCH,'CGILIB_OLB'/LIBRARY,SYS$INPUT:/OPTIONS
UCX$IPC_SHR/SHARE
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'WASD_OBJ_DIR'
$!
$!-----------------------------------------------------------------------------