$!'f$verify(0)
$ set on
$ on error then goto endCGIplusLoop
$ CGIplusLoop:
$    delete /symbol /local /global /all
$    cgiutl == "$CGI-BIN:[000000]CGIUTL"
$    cgiutl /plus /prefix="WWW_"
$    type = f$edit(f$parse(WWW_SCRIPT_FILENAME,,,"type"),"upcase")
$    if type .eqs. ".COM" then verb = "@" + WWW_SCRIPT_FILENAME
$    if type .eqs. ".EXE" then verb = "$" + WWW_SCRIPT_FILENAME
$    if f$type(verb) .eqs. "" then exit 676
$    verb
$!   'f$verify(0)
$    set on
$    on error then goto endCGIplusLoop
$    write sys$output f$trnlnm("CGIPLUSEOF")
$    goto CGIplusLoop
$ endCGIplusLoop:
$ exit $status
$!-----------------------------------------------------------------------------
$! COMRTEXE.COM
$!
$! An RTE wrapper for .COM and .EXE so they can be located anywhere, e.g.
$!
$!    exec /**.com (@cgi-bin:[000000]comrtexe.com)/web/*.com
$!    exec /**.exe (@cgi-bin:[000000]comrtexe.com)/web/*.exe
$!
$! Can be modified for other file types and execution environments.
$! CGI variables are present as global DCL symbols as per standard CGI.
$!
$! 06-NOV-2011  MGD  initial
$!-----------------------------------------------------------------------------