$!-----------------------------------------------------------------------------
$! WOTSUP.COM
$!
$! If called with P1 non-empty starts the WOTSUP image in a detached process.
$! Once in the detached process this procedure wraps the WOTSUP image allowing
$! command-line parameters to be supplied and restart after image errors, etc.
$!
$! This DCL procedure is intended to be copied somewhere site-specific,
$! perhaps WASD_ROOT:[STARTUP], and modified to suit local requirements.
$!
$! 28-DEC-2012  MGD  add @WASD_FILE_DEV for v10.0ff
$! 07-MAY-2005  MGD  initial
$!-----------------------------------------------------------------------------
$ IF F$TRNLNM("WASD_FILE_DEV") .NES. "" THEN @WASD_FILE_DEV
$!
$!(a default configuration, modify this or define your own /SYSTEM logical)
$ WASD_WOTSUP_PARAM = "/QUOTA=30 /HTTP=(5:10,403:5) /OPCOM"
$!
$ IF P1 .NES. ""
$ THEN
$    ON ERROR THEN CONTINUE
$    WASD_LOGS = F$TRNLNM("WASD_LOGS")
$    IF F$TRNLNM("WASD_WOTSUP_PROCESS") .EQS. "" -
        THEN DEFINE /USER /PROCESS WASD_WOTSUP_PROCESS -
                    "''WASD_LOGS'WOTSUP_''F$GETSYI("NODENAME")'.LOG"
$    RUN /DETACHED /AUTHORIZE SYS$SYSTEM:LOGINOUT -
         /PROCESS="WASD_WOTSUP" -
         /INPUT='F$ENVIRONMENT("PROCEDURE") -
         /OUTPUT='F$TRNLNM("WASD_WOTSUP_PROCESS")'
$    EXIT
$ ENDIF
$!
$ WOTSUP = "$WASD_EXE:WOTSUP"
$ IF F$TYPE(WASD_WOTSUP_PARAM) .EQS. "" THEN WASD_WOTSUP_PARAM = "/OPCOM"
$ WOTSUP_LOOP:
$    ON ERROR THEN CONTINUE
$    IF F$TRNLNM("WASD_WOTSUP_PARAM") .EQS. "" -
        THEN DEFINE /USER /PROCESS WASD_WOTSUP_PARAM "''WASD_WOTSUP_PARAM'"
$!   (parameters are read from the above logical name)
$    WOTSUP
$    STATUS = $STATUS
$!   (if exiting without an error then just restart)
$    IF STATUS THEN GOTO WOTSUP_LOOP
$!   (if a STOP/IMAGE or equivalent has been performed just exit)
$    IF STATUS .EQ. %X00002BDC THEN GOTO END_WOTSUP_LOOP
$!   (if an bugcheck exit then try again shortly)
$    WAIT 00:00:30
$    GOTO WOTSUP_LOOP
$ END_WOTSUP_LOOP:
$!-----------------------------------------------------------------------------