$!-----------------------------------------------------------------------------
$! STREAMLF.COM
$!
$! Convert P1 to stream-LF.
$!
$! 04-NOV-2002  MGD  massaged for in-line FDL
$! 04-NOV-2002  ABI  initial suggestion
$!-----------------------------------------------------------------------------
$ IF P1 .EQS. ""
$   THEN
$   WRITE SYS$OUTPUT "Usage: @STREAMLF <file>
$   EXIT
$   ENDIF
$!
$ PATTERN=F$PARSE(P1)-F$PARSE(P1,,,"VERSION")
$ OLDNAME=""
$ LOOP:
$   NAME=F$SEARCH(PATTERN)
$   IF NAME .EQS. "" THEN EXIT
$   NAME=F$PARSE(NAME)-F$PARSE(NAME,,,"VERSION")
$   IF NAME .EQS. OLDNAME THEN EXIT
$   OLDNAME=NAME
$   IF F$FILE(NAME,"RFM").EQS."STMLF" THEN GOTO LOOP
$   WRITE SYS$OUTPUT NAME
$   CONVERT/FDL=SYS$INPUT 'NAME' 'NAME'
FILE
        BEST_TRY_CONTIGUOUS     no
        CONTIGUOUS              no
        ORGANIZATION            sequential

RECORD
        BLOCK_SPAN              yes
        CARRIAGE_CONTROL        carriage_return
        FORMAT                  stream_LF
        SIZE                    0
$   IF F$PARSE(P1,,,"VERSION") .EQS. ";0" THEN PURGE 'NAME'
$ GOTO LOOP
$!-----------------------------------------------------------------------------