$!-----------------------------------------------------------------------------
$! HTTPD_ADMIN_REPORT_CLUSTER.COM
$!
$! Supports part of the [Cluster] functionality available from the Server
$! Administration menu.  Should be copied into HT_ROOT:[CGI-BIN].
$!
$! 28-JUN-2007  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ SAY = "WRITE SYS$OUTPUT"
$ IF F$GETSYI("CLUSTER_MEMBER") .EQS. "FALSE" THEN EXIT
$!
$ NODES = F$GETSYI("CLUSTER_NODES")
$ VOTES = F$GETSYI("CLUSTER_VOTES")
$ EVOTES = F$GETSYI("CLUSTER_EVOTES")
$ QUORUM = F$GETSYI("CLUSTER_QUORUM")
$ FTIME = F$EDIT(F$GETSYI("CLUSTER_FTIME"),"TRIM")
$ SAY "Cluster established ''FTIME'"
$ SAY "Currently ''NODES' nodes, ''VOTES' votes of ''EVOTES' expected " +-
      "with a quorum of ''QUORUM'"
$ SAY ""
$!
$ NWIDTH = 0
$ HWIDTH = 0
$ CONTEXT = ""
$ LOOP1:
$    ID = F$CSID(CONTEXT)
$    IF ID .EQS. "" THEN GOTO END_LOOP1
$    NODENAME = F$GETSYI("NODENAME",,ID)
$    HW_NAME = F$GETSYI("HW_NAME",,ID)
$    IF F$LENGTH(NODENAME) .GT. NWIDTH THEN NWIDTH = F$LENGTH(NODENAME)
$    IF F$LENGTH(HW_NAME) .GT. HWIDTH THEN HWIDTH = F$LENGTH(HW_NAME)
$    GOTO LOOP1
$ END_LOOP1:
$!
$ SAY F$FAO("    !#AS  !#AS  !8AS !6AS !AS", -
            NWIDTH, "Name", HWIDTH, "Hardware", "Version", "Member", "Votes")
$ SAY F$FAO("    !#*-  !#*-  !8*- !6*- !5*-", NWIDTH, HWIDTH)
$!
$ CONTEXT = ""
$ COUNT = 0
$ LOOP2:
$    ID = F$CSID(CONTEXT)
$    IF ID .EQS. "" THEN GOTO END_LOOP2
$    COUNT = COUNT + 1
$    NODENAME = F$GETSYI("NODENAME",,ID)
$    VERSION = F$GETSYI("VERSION",,ID)
$    HW_NAME = F$GETSYI("HW_NAME",,ID)
$    MEMBER = F$GETSYI("CLUSTER_MEMBER",,ID)
$    VOTES = F$GETSYI("NODE_VOTES",,ID)
$    SAY F$FAO("!2UL. !#AS  !#AS  !8AS !6AS !UL", -
               COUNT, NWIDTH, NODENAME, HWIDTH, HW_NAME, VERSION, MEMBER, VOTES)
$    GOTO LOOP2
$ END_LOOP2:
$ SAY ""
$ SAY F$FAO("!80*-")
$ SAY ""
$!
$!-----------------------------------------------------------------------------