$!-----------------------------------------------------------------'f$verify(0)
$! FIND_SSL.COM
$!
$! WASD VMS Web Services, Copyright (C) 1996-2015 Mark G.Daniel.
$! This program comes with ABSOLUTELY NO WARRANTY.
$! This is free software, and you are welcome to redistribute it under the
$! conditions of the GNU GENERAL PUBLIC LICENSE, version 3, or later version.
$! http://www.gnu.org/licenses/gpl.txt
$!
$! Locates the latest version of WASD OpenSSL and the OPENSSL executable.
$!
$! Creates the global symbols:
$!
$!    WASD_OPENSSL_DIR ... the top-level directory
$!    WASD_OPENSSL_VER ... the version number (e.g. "1.0.2")
$!    OPENSSL ............ the OpenSSL application foreign verb
$!
$! Defines the job-level logical name
$!
$!    OPENSSL_CONF
$!
$! to the default WASD OpenSSL configuration file.
$!
$! 26-JAN-2015  MGD  define OPENSSL_CONF /job logical
$! 04-APR-2010  MGD  OpenSSL v1.0.0 uses [.ALPHA] (rather than the WASD [.AXP])
$! 21-SEP-2006  MGD  allow for EFS by upper-casing
$! 08-JAN-2003  MGD  initial (with OpenSSL 0.9.7)
$!-----------------------------------------------------------------------------
$!
$ ss$_abort = 44
$ on controly then exit ss$_abort
$ archName = f$edit(f$getsyi("arch_name"),"upcase")
$!
$ wasdSSLdir = ""
$!(search for latest version in default WASD location)
$ wasdSSLdirLoop:
$    tmpDir = f$edit(f$search("WASD_ROOT:[SRC]OPENSSL-*_*_*.DIR"),"UPCASE")
$    if tmpDir .eqs. "" then goto wasdSSLdirLoopEnd
$    sslDirPos = f$locate("]OPENSSL",tmpDir)
$    wasdSSLdir = f$extract(0,sslDirPos,tmpDir) + "." + -
                  f$extract(sslDirPos+1,999,tmpDir) - ".DIR;1" + "]"
$    goto wasdSSLdirLoop
$ wasdSSLdirLoopEnd:
$!
$ if wasdSSLdir .eqs. ""
$ then
$    type sys$input

                 *******************************************
                 *  COULD NOT LOCATE WASD OPENSSL PACKAGE  *
                 *******************************************

$    exit ss$_abort
$ endif
$!
$ wasdSSLdir = f$edit(wasdSSLdir,"upcase")
$ pos = f$locate("OPENSSL-",wasdSSLdir)
$ ver = f$extract(pos+8,999,wasdSSLdir)
$ ver = f$element(0,"]",ver)
$ ver = f$element(0,"_",ver) + "." + f$element(1,"_",ver) + "." +-
        f$element(2,"_",ver)
$ WASD_OPENSSL_VER == ver
$ WASD_OPENSSL_DIR == wasdSSLdir
$ open_SSL = wasdSSLdir - "]" + "." + archName + ".EXE.APPS]OPENSSL.EXE"
$!
$ if f$search(open_SSL) .eqs. ""
$ then
$    type sys$input

                 ******************************************
                 *  COULD NOT LOCATE OPENSSL APPLICATION  *
                 ******************************************

$    exit ss$_abort
$ endif
$ configFileName = wasdSSLdir - "]" + ".WASD]DEFAULT.CNF"
$ if f$trnlnm("OPENSSL_CONF","LNM$JOB") .nes. "" -
     then deassign /job OPENSSL_CONF
$ define /job OPENSSL_CONF "''configFileName'"
$ OPENSSL == "$" + open_SSL
$!
$!-----------------------------------------------------------------------------