$!-----------------------------------------------------------------------------
$! BUILD_CONNECT_EXAMPLE.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 22-FEB-2021  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""CONNECT_EXAMPLE""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000,__CRTL_VER=70000000)"
$ INCLUDES = ""
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC,ADDRCONSTEXT))"
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' CONNECT_EXAMPLE
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    SET NOON
$    SET VERIFY
$    LINK /EXECUTABLE=WASD_EXE:CONNECT_EXAMPLE.EXE 'OBJECT_DIR'CONNECT_EXAMPLE
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------