$!-----------------------------------------------------------------------------
$! BUILD_MOD_CGIPLUSTEST.COM
$!
$! build VMS Apache module equivalent
$! developed on VSI AXPVMS CSWS V2.4-38C (YMMV)
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 19-APR-2020  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ on controly then exit 44
$ P1 = f$edit(P1,"upcase")
$!
$ @wasd_root:[src]archer.com "MOD_CGIPLUSTEST"
$!
$ defines = " /define=(__VMS_VER=70000000,__CRTL_VER=70000000,APACHE_MOD)"
$ includes = " /include=[src.misc]"
$ warnings=  " /warning=(DISABLE=(PREOPTW,IMPLICITFUNC))"
$!
$ cc_options = "/decc /optimize /stand=relaxed_ansi /pointer_size=32 " +-
               "/define=(_USE_STD_STAT) /names=(as_is,shortened)" +-
               includes + defines + warnings
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "COMPILE"
$ then
$    set noon
$    set verify
$    cc 'cc_options' /object='wasd_obj_dir'mod_cgiplustest -
        cgiplustest+apache$root:[include]APACHE$LIBRARY.TLB/lib
$!   'f$verify(0)
$    set on
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "LINK"
$ then
$    set noon
$    set verify
$    link /share /executable='wasd_obj_dir'mod_cgiplustest.exe -
     'wasd_obj_dir'mod_cgiplustest,sys$input/opt
CASE_SENSITIVE=YES
SYMBOL_VECTOR=(cgiplustest_module=DATA)
APACHE$APR_SHR/share
APACHE$HTTPD_SHR/share
$!   'f$verify(0)
$    set on
$ endif
$ purge /nolog 'wasd_obj_dir'
$!
$!-----------------------------------------------------------------------------