$!-----------------------------------------------------------------------------
$! BUILD_LOOKAGENT.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 01-JUN-2021  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ @WASD_ROOT:[SRC]ARCHER.COM "LOOKAGENT"
$!
$ VMS_VERSION = F$INTEGER(F$EXTRACT(1,1,F$GETSYI("VERSION"))) * 10 +-
                F$INTEGER(F$EXTRACT(3,1,F$GETSYI("VERSION")))
$ IF VMS_VERSION .LT. 73
$ THEN
$    WRITE SYS$OUTPUT "BUILD: requires a minimum of VMS V7.3"
$    EXIT
$ ENDIF
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$ INCLUDES = " /INCLUDE=[SRC.MISC]"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW))"
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='WASD_OBJ_DIR' LOOKAGENT
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    CGILIB_OBJ = "[SRC.MISC.OBJ_''WASD_ARCH_NAME']CGILIB.OBJ"
$    SET NOON
$    SET VERIFY
$    LINK /NOTRACE /EXECUTABLE=WASD_EXE:LOOKAGENT.EXE -
     'WASD_OBJ_DIR'LOOKAGENT,'CGILIB_OBJ'
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'WASD_OBJ_DIR'
$!
$!-----------------------------------------------------------------------------