$!-----------------------------------------------------------------------------
$! WASDVERBS.COM
$!
$! Assign the WASD Web Admin foreign verbs.
$! If P1 is an integer between 2 and 15 sets up for that WASD environment.
$! If the SSL HTTPd image is found in WASD_EXE: then is assumes you use it.
$! To use this directly include "$ @WASD_ROOT:[EXAMPLE]WASDVERBS" in the
$! appropriate user account LOGIN.COMs.
$! 
$! COPYRIGHT
$! ---------
$! Copyright (C) 1996-2021 Mark G.Daniel
$! 
$! Licensed under the Apache License, Version 2.0 (the "License");
$! you may not use this file except in compliance with the License.
$! You may obtain a copy of the License at
$! 
$!    http://www.apache.org/licenses/LICENSE-2.0
$! 
$! Unless required by applicable law or agreed to in writing, software
$! distributed under the License is distributed on an "AS IS" BASIS,
$! WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
$! See the License for the specific language governing permissions and
$! limitations under the License.
$!
$! VERSION HISTORY
$! ---------------
$! 08-SEP-2021  MGD  OpenSSL 3.0
$! 22-SEP-2018  MGD  add (WASD) OPENSSL
$! 02-OCT-2011  MGD  add EXORCISER
$! 06-JUL-2009  MGD  v10 and pre-v10 logical names
$!                   WASD autonomous environments
$! 29-MAY-2005  MGD  add WOTSUP
$! 12-OCT-2003  MGD  add HTADMIN
$! 04-NOV-2002  MGD  add SECHAN, made STREAMLF a procedure
$! 20-MAY-2001  MGD  add MD5DIGEST, remove UN/SCRUNCH
$! 22-NOV-2000  MGD  initial
$!-----------------------------------------------------------------------------
$!
$!(set up process' LNM$_FILE_DEV for v10.0 and later)
$ wasd_file_dev = "WASD_FILE_DEV"
$ if f$type(P1) .eqs. "INTEGER" .and. P1 .gt. 1 then -
     wasd_file_dev = wasd_file_dev + "_" + P1
$ if f$trnlnm(wasd_file_dev) .nes. "" then @'wasd_file_dev'
$!
$ if f$trnlnm("WASD_EXE") .nes. ""
$    then wasd_exe = "WASD_EXE:"
$    else wasd_exe = "HT_EXE:"
$ endif
$ if f$search("''wasd_exe'httpd_ssl.exe") .eqs. ""
$    then httpd == "$''wasd_exe'HTTPD.EXE;0"
$    else httpd == "$''wasd_exe'HTTPD_SSL.EXE;0"
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "SSL"
$ then
$!   (if P1 is "SSL" then force reassignment of any OPENSSL verb)
$    if p1 .nes. ""
$    then
$       openssl == ""
$       define /user sys$error nl:
$       define /user sys$output nl:
$       delete /symbol /nolog /global openssl
$    endif
$    openssl = ""
$    define /user sys$error nl:
$    define /user sys$output nl:
$    delete /symbol /nolog openssl
$    arch_name = f$getsyi("arch_name")
$    if f$type(openssl) .eqs. ""
$    then 
$!      (WASD OpenSSL v3.0)
$       ssl_loop3:
$          exe = f$search("wasd_root:[src.openssl-3_*.wasd.''arch_name']openssl.exe")
$          if exe .eqs. "" then goto end_ssl_loop3
$          exe = exe - f$parse(exe,,,"version")
$          openssl == "$''exe'"
$          goto ssl_loop3
$       end_ssl_loop3:
$       if f$type(openssl) .eqs. ""
$       then 
$!         (WASD OpenSSL v1.1)
$          ssl_loop1:
$             exe = f$search("wasd_root:[src.openssl-1_1_*.wasd.''arch_name']openssl.exe")
$             if exe .eqs. "" then goto end_ssl_loop1
$             exe = exe - f$parse(exe,,,"version")
$             openssl == "$''exe'"
$             goto ssl_loop1
$          end_ssl_loop1:
$       endif
$    endif
$    if f$type(openssl) .eqs. ""
$    then 
$!      (WASD OpenSSL v1.0)
$       ssl_loop0:
$          exe = f$search("wasd_root:[src.openssl-1_0_*.''arch_name'.exe.apps]openssl.exe")
$          if exe .eqs. "" then goto end_ssl_loop0
$          exe = exe - f$parse(exe,,,"version")
$          openssl == "$''exe'"
$       goto ssl_loop0
$       end_ssl_loop0:
$    endif
$ endif
$!
$ ab ==          "$''wasd_exe'AB"
$ exorciser ==   "$''wasd_exe'EXORCISER"
$ htadmin ==     "$''wasd_exe'HTADMIN"
$ httpdmon ==    "$''wasd_exe'HTTPDMON"
$ md5digest ==   "$''wasd_exe'MD5DIGEST"
$ qdlog*stats == "$''wasd_exe'QDLOGSTATS"
$ sechan ==      "$''wasd_exe'SECHAN"
$ streamlf ==    "@''wasd_exe'STREAMLF"
$ wasdfiledev == "@wasd_file_dev"
$ wasdwhich ==   "write sys$output f$parse(""WASD_ROOT:[000000]"",,,,""no_conceal"")-"".][000000""-"".;"""
$ wb ==          "$''wasd_exe'WB"
$ wotsup ==      "$''wasd_exe'WOTSUP"
$!-----------------------------------------------------------------------------