$!-----------------------------------------------------------------------------
$! BUILD_WB.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 02-JUN-2001  MGD  initial development
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""WB""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
            "__CRTL_VER=70000000,WB)"
$ INCLUDES = ""
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW))"
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
               INCLUDES + DEFINES + WARNINGS
$ IF ARCH_NAME .EQS. "IA64" THEN CC_OPTIONS = CC_OPTIONS + "/FLOAT=IEEE"
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR'WB WB
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    SET NOON
$    SET VERIFY
$    LINK /EXECUTABLE=WASD_EXE:WB.EXE -
     'OBJECT_DIR'WB
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------