$!-----------------------------------------------------------------------------
$! BUILD_PROXYMUNGE.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == SSL or empty
$!
$! 22-SEP-2007  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""PROXYMUNGE""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ IF P2 .EQS. "WASD_SSL"
$ THEN
$    IF F$TRNLNM("SSLROOT") .EQS. ""
$    THEN
$       WRITE SYS$OUTPUT ""
$       WRITE SYS$OUTPUT "Please provide the following logical names:"
$       WRITE SYS$OUTPUT "$ DEFINE /PROCESS /TRANSLATION=CONCEALED " +-
                         "SSLROOT device:[WASD_ROOT.SRC.OPENSSL_n_n_n.]"
$       WRITE SYS$OUTPUT "$ DEFINE /PROCESS OPENSSL SSLROOT:[INCLUDE.OPENSSL]"
$       WRITE SYS$OUTPUT ""
$       DIRECTORY WASD_ROOT:[SRC]OPENSSL*.DIR
$       WRITE SYS$OUTPUT ""
$       EXIT
$    ENDIF
$ ENDIF
$!
$ DATETIME = F$EDIT(F$TIME(),"TRIM")
$ MUNGE_VIA_SSL = ""
$ IF P2 .EQS. "OPEN_SSL" THEN MUNGE_VIA_SSL = ",MUNGE_VIA_SSL=1"
$ IF P2 .EQS. "VMS_SSL" THEN MUNGE_VIA_SSL = ",MUNGE_VIA_SSL=1"
$ IF P2 .EQS. "WASD_SSL" THEN MUNGE_VIA_SSL = ",MUNGE_VIA_SSL=1"
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE," +-
                       "BUILD_DATETIME=""""""''DATETIME'""""""''MUNGE_VIA_SSL')"
$!
$ INCLUDES = " /INCLUDE=[SRC.MISC]"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC," +-
                         "NEEDCONSTEXT,ADDRCONSTEXT))"
$!
$ IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "VAX"
$ THEN
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=VAXC /PREFIX=ALL" +-
                  INCLUDES + DEFINES + WARNINGS
$ ELSE
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=VAXC /PREFIX=ALL" +-
                  INCLUDES + DEFINES + WARNINGS
$ ENDIF
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' PROXYMUNGE
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    CGILIB_OLB = "[SRC.MISC.OBJ_''ARCH_NAME']CGILIB.OLB"
$    SET NOON
$    IF P2 .EQS. "OPEN_SSL"
$    THEN
$       SET VERIFY
$       LINK /EXECUTABLE=WASD_EXE:PROXYMUNGE.EXE -
        [.OBJ_'ARCH_NAME']PROXYMUNGE,'CGILIB_OLB'/LIBRARY,-
        SYS$INPUT/OPTIONS
SSLLIB:LIBSSL.OLB/LIBRARY
SSLLIB:LIBCRYPTO.OLB/LIBRARY
$!      'F$VERIFY(0)
$    ENDIF
$    IF P2 .EQS. "VMS_SSL"
$    THEN
$       SET VERIFY
$       LINK /EXECUTABLE=WASD_EXE:PROXYMUNGE.EXE -
        [.OBJ_'ARCH_NAME']PROXYMUNGE,'CGILIB_OLB'/LIBRARY,-
        SYS$INPUT/OPTIONS
SYS$COMMON:[SYSLIB]SSL$LIBSSL_SHR32.EXE/SHARE
SYS$COMMON:[SYSLIB]SSL$LIBCRYPTO_SHR32.EXE/SHARE
$!      'F$VERIFY(0)
$    ENDIF
$    IF P2 .EQS. "WASD_SSL"
$    THEN
$       DEFINE /PROCESS WASD_SSL "SSLROOT:[''ARCH_NAME'.EXE.SSL]"
$       DEFINE /PROCESS WASD_CRYPTO "SSLROOT:[''ARCH_NAME'.EXE.CRYPTO]"
$       SET VERIFY
$       LINK /EXECUTABLE=WASD_EXE:PROXYMUNGE.EXE -
        [.OBJ_'ARCH_NAME']PROXYMUNGE,'CGILIB_OLB'/LIBRARY,-
        SYS$INPUT/OPTIONS
WASD_SSL:LIBSSL.OLB/LIBRARY
WASD_CRYPTO:LIBCRYPTO.OLB/LIBRARY
$!      'F$VERIFY(0)
$       DEASSIGN /PROCESS WASD_SSL
$       DEASSIGN /PROCESS WASD_CRYPTO
$    ENDIF
$    IF P2 .EQS. ""
$    THEN
$       SET VERIFY
$       LINK /EXECUTABLE=WASD_EXE:PROXYMUNGE.EXE -
        [.OBJ_'ARCH_NAME']PROXYMUNGE,'CGILIB_OLB'/LIBRARY
$!      'F$VERIFY(0)
$    ENDIF
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------