$!-----------------------------------------------------------------------------
$! BUILD_AB.COM
$! Only supported for VMS V7.n and above.
$! Use defines to suppress or circumvent use of the Apache build environment.
$! Components: AB.C, AB_AP_BASE64.C, BUILD_AB.COM (this file)
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 24-JAN-2002  MGD  ApacheBench v1.3c
$! 15-NOV-2000  MGD  RELAXED compilation 
$! 23-MAY-2000  MGD  ApacheBench v1.1
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""AB""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ IF F$INTEGER(F$EXTRACT(1,1,F$GETSYI("NODE_SWVERS"))) .LT. 7
$ THEN
$    WRITE SYS$OUTPUT """AB"" requires at least VMS V7.n"
$    EXIT
$ ENDIF
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000,__CRTL_VER=70000000," +-
            "FD_SETSIZE=256,NO_APACHE_INCLUDES,NO_WRITEV," +-
            """API_EXPORT(t)""=""t"")"
$ INCLUDES = ""
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC))"
$!
$ IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "VAX"
$ THEN
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
                  INCLUDES + DEFINES + WARNINGS
$ ELSE
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
                  INCLUDES + DEFINES + WARNINGS
$ ENDIF
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' AB
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' AB_AP_BASE64
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    SET NOON
$    SET VERIFY
$    LINK /EXECUTABLE=WASD_EXE:AB.EXE -
     'OBJECT_DIR'AB, -
     'OBJECT_DIR'AB_AP_BASE64
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------