$!-----------------------------------------------------------------------------
$! BUILD_CGILIB.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! (actually the LINK options just creates and populates the object library)
$!
$! 07-OCT-2004  JFP  build shareable image
$! 07-JUL-2001  MGD  minor massaging
$! 28-OCT-2000  MGD  initial, compile into object module
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""CGILIB object module""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ INCLUDES = "/INCLUDE=[]"
$ DEFINES = "/DEFINE=(__VMS_VER=70000000," +-
            "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL " +-
               "/WARNINGS=(DISABLE=(PREOPTW)) 'DEFINES' 'INCLUDES'"
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR'CGILIB CGILIB 
$    IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .NES. "VAX"
$    THEN
$       CC 'CC_OPTIONS'/NAME=AS_IS /OBJECT='OBJECT_DIR'CGILIB_AS_IS CGILIB 
$    ENDIF
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    IF F$SEARCH("[.OBJ_''ARCH_NAME']CGILIB.OLB") .EQS. "" -
        THEN LIBRARY /CREATE /OBJECT [.OBJ_'ARCH_NAME']CGILIB.OLB
$    IF (F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .NES. "VAX") .AND. -
		(F$SEARCH("[.OBJ_''ARCH_NAME']CGILIB_AS_IS.OLB") .EQS. "") -
        THEN LIBRARY /CREATE /OBJECT [.OBJ_'ARCH_NAME']CGILIB_AS_IS.OLB
$    SET NOON
$    SET VERIFY
$    LIBRARY /OBJECT /REPLACE 'OBJECT_DIR'CGILIB.OLB 'OBJECT_DIR'CGILIB.OBJ
$    IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .NES. "VAX"
$    THEN
$       LIBRARY /OBJECT /REPLACE 'OBJECT_DIR'CGILIB_AS_IS.OLB -
                                 'OBJECT_DIR'CGILIB_AS_IS.OBJ
$       LINK /SHARE=WASD_EXE:CGILIBSHR32.EXE -
             CGILIBSHR.OPT/OPT,'OBJECT_DIR'CGILIB_AS_IS.OBJ
$    ENDIF
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------