$!-----------------------------------------------------------------------------
$! BUILD_CGIPLUSTEST.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == Optional location of CGILIB object module (defaults to [.MISC])
$!
$! 19-OCT-2009  MGD  re-development
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""CGIPLUSTEST""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$ INCLUDES = " /INCLUDE=[SRC.MISC]"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC,ADDRCONSTEXT))"
$!
$ IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "VAX"
$ THEN
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
                  INCLUDES + DEFINES + WARNINGS
$ ELSE
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
                  INCLUDES + DEFINES + WARNINGS
$ ENDIF
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' CGIPLUSTEST
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    CGILIB_OBJ = "[SRC.MISC.OBJ_''ARCH_NAME']CGILIB.OBJ"
$    SET NOON
$    SET VERIFY
$    LINK /EXECUTABLE=WASD_EXE:CGIPLUSTEST.EXE -
     'OBJECT_DIR'CGIPLUSTEST,'CGILIB_OBJ'
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------