$!-----------------------------------------------------------------------------
$! STARTUP_DECNET.COM
$!
$! Example startup for WASD DECnet-based scripting with OSU scripting support.
$! This procedure should be called from the HTTP server startup procedure
$! before actually starting-up the HTTPd.
$!
$! NOTE that using this procedure will cause (almost certainly undesireable)
$! interactions between WASD and OSU on sites that are attempting to run both.
$!
$! 17-JUL-1998  MGD  renamed from STARTUP_OSU.COM
$! 10-JAN-1998  MGD  initial
$!-----------------------------------------------------------------------------
$!
$! -----------------------
$! NETSERVER logical names
$! -----------------------
$!
$!(uncomment either of these definitions as appropriate)
$!! DEFINE /NOLOG /SYSTEM NETSERVER$TIMEOUT "0 00:00:30"
$!! DEFINE /NOLOG /SYSTEM NETSERVER$SERVERS_HTTP$SERVER 5
$!
$! -----------------
$! OSU Logical Names
$! -----------------
$!
$ HT_ROOT = F$TRNLNM("HT_ROOT") - ".]" + ".SRC.OSU.]"
$ DEFINE /NOLOG /SYSTEM /EXEC /TRANS=CONCEALED WWW_ROOT 'HT_ROOT'
$ DEFINE /NOLOG /SYSTEM /EXEC HTBIN CGI-BIN:[000000]
$!(allows the OSU v3.3a WWWEXEC.COM to reuse DECnet connections)
$ DEFINE /NOLOG /SYSTEM /EXEC WWW_SCRIPT_MAX_REUSE 999
$!
$ IF F$SEARCH("SYS$SYSTEM:NCL.EXE") .NES. ""
$ THEN
$!   -----------------------------
$!   DECnet-Plus (Phase-V) Objects
$!   -----------------------------
$    MCR NCL
!
! WASD CGI object
!
CREATE NODE 0 SESSION CONTROL APPLICATION CGIWASD
SET NODE 0 SESSION CONTROL APPLICATION CGIWASD ADDRESSES = {NAME=CGIWASD} -
,CLIENT =  -
,INCOMING ALIAS = TRUE -
,INCOMING PROXY = TRUE -
,OUTGOING ALIAS = FALSE -
,OUTGOING PROXY = TRUE -
,NODE SYNONYM = TRUE -
,IMAGE NAME = CGI-BIN:[000000]CGIWASD.COM -
,INCOMING OSI TSEL =  
!
! OSU object
!
CREATE NODE 0 SESSION CONTROL APPLICATION WWWEXEC
SET NODE 0 SESSION CONTROL APPLICATION WWWEXEC ADDRESSES = {NAME=WWWEXEC} -
,CLIENT =  -
,INCOMING ALIAS = TRUE -
,INCOMING PROXY = TRUE -
,OUTGOING ALIAS = FALSE -
,OUTGOING PROXY = TRUE -
,NODE SYNONYM = TRUE -
,IMAGE NAME = CGI-BIN:[000000]WWWEXEC.COM -
,INCOMING OSI TSEL =  
$!
$ ELSE
$!   -----------------------
$!   DECnet Phase-IV Objects
$!   -----------------------
$    MCR NCP
! WASD CGI object (volatile)
SET OBJECT CGIWASD NUMBER 0 FILE CGI-BIN:[000000]CGIWASD.COM
! OSU object (volatile)
SET OBJECT WWWEXEC NUMBER 0 FILE CGI-BIN:[000000]WWWEXEC.COM
$!
$ ENDIF
$!-----------------------------------------------------------------------------