$ goto start
$!
$! This command procedure is an example of using the DCL lexical functions
$! that return CPU and partition information.
$!
$ start:
$ say :== "write sys$output"
$!
$! get system type
$ say ""
$ say f$getsyi("hw_name")
$!
$! get QBBs in system
$ qbbs = f$getsyi("hp_config_sbb_cnt")
$!
$! get configured soft partitions
$ csp = f$getsyi("hp_config_sp_cnt")
$!
$! get active soft partitions 
$ asp = f$getsyi("hp_active_sp_cnt")
$!
$! get active CPUs in hard partition
$ hpcpus = f$getsyi("hp_active_cpu_cnt")
$!
$! get active CPUs in this soft partitions
$ spcpus = f$getsyi("activecpu_cnt")
$! 
$! get Galaxy license units
$ pipe show license/us/ful openvms-galaxy | search sys$input -
  "units loaded" | (read sys$input line ; units = f$element -
  (2," ",f$edit(line,"trim,compress")) ; define/job glx$$license_units &units)
$!
$ units = f$trnlnm("glx$$license_units", "lnm$job")
$ if (units .le. 0) .or. (units .gt. 6400) then units = 0
$ say ""
$ say qbbs, "	QBBs in this Hard Partition"
$ say csp, "	Configured Soft Partitions in this Hard Partition"
$ say asp, "	Active Soft Partitions in this Hard Partition"
$ say hpcpus, "	Active CPUs in this Hard Partition"
$ say spcpus, "	Active CPUs in this Soft Partition"
$ say units, "	Galaxy license units loaded for this Soft Partition"
$ say ""
$ deassign/job glx$$license_units
$ exit