.TITLE	STOP_BUS Stop the LAVc Protocol on the Specified LAN Adapter.
	.SBTTL	External Definitions
	.IDENT	'X-5'

        ;-
        ; This sample program  stops the  LAVc  protocol (SCA)  on a specified
        ; LAN adapter.
        ;
        ;                ************* CAUTION **************
        ; Stopping the LAVc protocol on all LAN adapters will cause satellites
        ; to hang and  may cause cluster systems  to crash with a CLUEXIT bug-
        ; check.
        ;
        ;                         ****  NOTE  ****
        ; Whenever LAVC$STOP_BUS successfully executes, a "DEVICE ATTENTION...
        ; NI-SCS SUB-SYSTEM...FATAL ERROR DETECTED BY DATALINK..." error, with
        ; a hexidecimal value of 00000001 in the first longword  of the STATUS
        ; field and a hexidecimal value of 00001201 in the second longword  of
        ; the STATUS field  will be generated and written  to the system error
        ; log. This is expected behavior and may be safely ignored. Note, how-
        ; ever, that if the first longword  of the STATUS field contains other
        ; than the hexidecimal value 00000001, then an actual error has occur-
        ; red and further investigation may be warranted.
        ;+

	.DISABLE	GLOBAL

	.EXTERNAL	LIB$GET_FOREIGN
	.EXTERNAL	SYS$LAVC_STOP_BUS

	.PAGE
	.SBTTL	Local Data Definitions.

	.PSECT	DATA	PAGE, RD, WRT, NOEXE, NOSHR

BUS_PROMPT::	.ASCID	"Bus Name: "

	.ALIGN	QUAD

BUFFER_LENGTH	=	256

BUS_NAME::	.LONG		BUFFER_LENGTH
		.ADDRESS	BUFFER
BUFFER::	.BLKB		BUFFER_LENGTH

	.PAGE
	.SBTTL	Stop BUS Program.

	.PSECT	CODE	PAGE, RD, NOWRT, EXE, SHR

	.SHOW	MEB

STOP_BUS:
	.CALL_ENTRY	MAX_ARGS=0

;
;		Get the user specified BUS name.
;

	PUSHAL	BUS_NAME		; Return length address.
	PUSHAB	BUS_PROMPT		; Prompt descriptor address.
	PUSHAB	BUS_NAME		; BUS name descriptor address.
	CALLS	# 3, G^ LIB$GET_FOREIGN	; Get the BUS name.
	BLBC	R0, 99$

;
;		Stop the BUS.
;

	PUSHAQ	BUS_NAME
	CALLS	# 1, G^ SYS$LAVC_STOP_BUS

99$:
	RET

	.END	STOP_BUS