$	Verify_state = f$verify ( 0 )
$	Set noon
$	Exit_status = 4
$	Current_dir = f$trnlnm ( "sys$disk" ) + f$directory ( )
$	Com_proc = f$environment ( "procedure" )
$	New_dir = f$parse ( com_proc, , , "device", "no_conceal" ) + f$parse ( com_proc, , , "directory", "no_conceal" ) - "]["
$!
$!		Define the input parameters.
$!
$	File := 'p1'		! Example: LAVC$FAILURE_ANALYSIS.MAR
$	Debug := 'p2'		! Normally blank.
$	Dir_spec := 'p3'	! Normally blank.
$!
$!		Apply the default values.
$!
$	If f$length ( dir_spec ) .eq. 0 then dir_spec = new_dir
$	Set default 'dir_spec'
$	If f$length ( debug ) .ne. 0 then debug = "/debug "
$	If f$length ( file ) .eq. 0
$	Then
$		Write sys$output "    Please specify file name as P1"
$		Goto done
$	Endif
$	File_spec = f$parse ( file, , , "device" ) + f$parse ( file, , , "directory" ) + -
		    f$parse ( file, , , "name" ) + f$parse ( file, , , "type" ) + f$parse ( file, , , "version" )
$	File_name = f$parse ( file, , , "name" )
$!
$!		Only execute this procedure from batch.
$!
$	If f$mode ( ) .eqs. "INTERACTIVE" .and. f$trnlnm ( "no_batch" ) .eqs. ""
$	Then
$		If f$getqui ( "display_queue", "queue_stopped", "SYS$BATCH" ) .eqs. "FALSE"
$		Then
$			Submit /restart /keep /noprint /notify /log='new_dir''file_name'.log /name=mac_'file_name' 'com_proc' -
				/parameters=("''file'","''debug'","''dir_spec'")
$			Exit_status = 1
$			Goto done
$		Endif
$	Endif
$!
$!		Set the correct environment for the build.
$!
$	Set verify
$	Set output=0:0:10.0
$	If f$search ( "''file_name'.log;-1" ) .nes. "" then purge /log 'file_name'.log
$!
$!		Build the specified module.
$!
$	If f$search ( "''file_name'.lis" ) .nes. "" then delete /log 'file_name'.lis;*
$	If f$search ( "''file_name'.obj" ) .nes. "" then delete /log 'file_name'.obj;*
$	If f$search ( "''file_name'.map" ) .nes. "" then delete /log 'file_name'.map;*
$	If f$search ( "''file_name'.exe" ) .nes. "" then delete /log 'file_name'.exe;*
$	On warning then goto done
$		Macro /migration /debug /list='file_name'.lis /obj='file_name'.obj -
sys$library:arch_defs.mar+'file_spec'+sys$library:lib.mlb/lib
$		Link /alpha'debug'/map /full /cross /exe='file_name'.exe 'file_name'.obj
$!
$	Exit_status = 1
$!
$ Done:
$	Set noon
$	Temp_verify = f$verify ( verify_state )
$	Exit 'exit_status'