$ ! Build the Motif DECburger Demo
$ ! The files decburger.uid and decburger.exe will be produced by this 
$ ! command procedure.
$ !
$ ! Make sure that the prerequisite files and logicals exist.  This command
$ ! procedure requires that the DECwindows programming and user environments
$ ! have been installed and that the DECW$STARTUP command procedure has been 
$ ! invoked.  
$ !
$ vax = "False"
$ if f$getsyi("ARCH_NAME") .eqs. "VAX" then vax = "True"
$
$ if f$search("sys$system:decw$uilmotif.exe") .nes. "" then goto libskitok
$ write sys$output "DECwindows programming environment not installed."
$ write sys$output "DECburger demo build aborted."
$ exit
$
$libskitok:
$ if f$search("sys$share:decw$xlibshr.exe") .nes. ""	.and. -
     f$search("sys$share:decw$dxmlibshr.exe") .nes. ""	then goto appskitok
$ write sys$output "DECwindows user environment not installed."
$ write sys$output "DECburger demo build aborted."
$ exit
$
$appskitok:
$ if f$trnlnm("decw$include") .nes. ""	.and. -
     f$trnlnm("decw$examples") .nes. ""	then goto startupok
$ write sys$output "You must invoke @DECW$STARTUP before using this procedure."
$ write sys$output "DECburger demo build aborted."
$ exit
$
$startupok:
$ decc = "False"
$ if (.not. vax .or. f$search("sys$system:vaxc.exe") .eqs. "")
$ then
$   if f$search("sys$system:decc$compiler.exe") .nes. ""
$   then
$     decc = "True"
$   else
$     write sys$output "C compiler is not available."
$     write sys$output "DECburger demo build aborted."
$     exit
$   endif
$ endif
$
$ if decc
$ then
$   define/nolog decc$user_include decw$examples,decw$include,sys$library
$   define/nolog decc$system_include decc$user_include
$   if f$search("sys$library:decc$rtldef.tlb") .nes. "" then -
	define/nolog decc$text_library sys$library:decc$rtldef.tlb
$   cc = "cc/standard=vaxc"
$ else
$   define/nolog c$include decw$examples,decw$include,sys$library
$   define/nolog vaxc$include c$include
$   if f$search("sys$library:vaxcdef.tlb") .nes. "" then -
	define/nolog c$library sys$library:vaxcdef.tlb
$   cc = "cc"
$ endif
$ !
$ ! Build DECburger and run it
$ !
$ write sys$output "Compiling DECburger.UIL..."
$ define/user/nolog uil$include decw$include
$ uil/motif decw$examples:decburger
$
$ write sys$output "Compiling DECburger.C..."
$ cc decw$examples:decburger
$
$ write sys$output "Linking DECburger..."
$ link decburger,sys$input/opt
sys$share:decw$mrmlibshr12/share
sys$share:decw$dxmlibshr12/share
sys$share:decw$xmlibshr12/share
sys$share:decw$xtlibshrr5/share
sys$share:decw$xlibshr/share
$
$ write sys$output "Copying DECburger bitmap and help library"
$ copy decw$examples:icon.xbm *
$ library/help/create decburger.hlb decw$examples:decburger.hlp
$
$ write sys$output "Running DECburger..."
$ run decburger
$
$ exit