$ !
$ ! Script to build the color customizer demo on VMS
$ !
$ ! Assumes that the following files have been copied from DECW$EXAMPLES
$ ! to the current build directory
$ !
$ ! CUSTOM.C
$ ! CUSTOM.UIL
$ ! CUSTOMIMAGE.DAT
$ ! XSETROOT_CUST.C
$ 
$ vax = "False"
$ if f$getsyi("ARCH_NAME") .eqs. "VAX" then vax = "True"	!Verified for I64 port - DMP
$
$ decc = "False"
$ if (.not. vax .or. f$search("sys$system:vaxc.exe") .eqs. "")
$ then
$   if f$search("sys$system:decc$compiler.exe") .nes. ""
$   then
$     decc = "True"
$   else
$     write sys$output "C compiler is not available."
$     write sys$output "Color customizer demo build aborted."
$     exit
$   endif
$ endif
$
$ if decc
$ then
$   define/nolog decc$user_include decw$examples,decw$include,sys$library
$   define/nolog decc$system_include decc$user_include
$   if f$search("sys$library:decc$rtldef.tlb") .nes. "" then -
	define/nolog decc$text_library sys$library:decc$rtldef.tlb
$   cc = "cc/standard=vaxc"
$ else
$   define/nolog c$include decw$examples,decw$include,sys$library
$   define/nolog vaxc$include c$include
$   if f$search("sys$library:vaxcdef.tlb") .nes. "" then -
	define/nolog c$library sys$library:vaxcdef.tlb
$   cc = "cc"
$ endif
$
$ write sys$output "Compiling custom.c..."
$ cc custom.c
$ write sys$output "Linking custom..."
$ link custom,sys$input/opt
sys$share:decw$mrmlibshr12/share
sys$share:decw$dxmlibshr12/share
sys$share:decw$xmlibshr12/share
sys$share:decw$xtlibshrr5/share
sys$share:decw$xlibshr/share
$ 
$ write sys$output "Compiling custom.uil..."
$ uil/motif custom.uil
$
$ write sys$output "Compiling xsetroot_cust.c..."
$ cc xsetroot_cust.c
$ write sys$output "Linking xsetroot_cust..."
$ link xsetroot_cust,sys$input/opt
sys$share:decw$mrmlibshr12/share
sys$share:decw$dxmlibshr12/share
sys$share:decw$xmlibshr12/share
sys$share:decw$xtlibshrr5/share
sys$share:decw$xlibshr/share
$ 
$ write sys$output "Color customizer build finished"
$
$ exit