$   verify = 'F$VERIFY(0)'
$   completion_code = 1
$   SET NOON
$!++
$! Facility:
$!  DECEVENT$UPDATE_HELP.COM
$!
$! Abstract:
$!  This command procedure can be run either from a kitinstal.com during an
$!  installation, or by itself from the command line.  It will attempt to add
$!  the DECevent help to the system help library.  If the library is locked,
$!  this command procedure prints out a message to the user telling them to try
$!  again latter.  Otherwise, the .hlp file is put in the system help library.
$!
$! Author:
$!  Chad Masters
$!
$! Parameters:
$!
$!   Param			    Description
$!   =====	========================================================
$!
$!    P1:	This is the name of the HELP file to install.
$!
$!    P2:	[~tbs~]
$!
$!    P3:	[~tbs~]
$!
$!    P4:	[~tbs~]
$!
$!    P5:	[~tbs~]
$!
$!    P6:	[~tbs~]
$!
$!    P7:	[~tbs~]
$!
$!    P8:	[~tbs~]
$!
$! Creation Date:  7-FEB-1994 
$!
$! Modification History:
$!
$!		8-Sep-1998	CSK	Commented out the section that deletes the update help files procedure at a later time
$!					The delete of this procedure has been moved to the deinstal.com
$!--
$!
$   ASK       := READ SYS$COMMAND/PROMPT=
$   SAY       := WRITE SYS$OUTPUT
$   TRUE       = "TRUE"
$   FALSE      = "FALSE"
$   DELETE    := DELETE
$   PURGE     := PURGE
$   OPEN      := OPEN
$   DIRECTORY := DIRECTORY
$   TYPE      := TYPE
$   CLOSE     := CLOSE
$   CALL      := CALL
$   COPY      := COPY
$   DEFINE    := DEFINE
$   DEASSIGN  := DEASSIGN
$   CREATE    := CREATE
$   PRINT     := PRINT
$   SET       := SET
$   SHOW      := SHOW
$   WRITE     := WRITE
$   READ      := READ
$
$   UPD_HELP_TMP_FILE := SYS$HELP:UPD_HELP.DAT
$
$   This_Dir  = F$ENVIRONMENT("PROCEDURE")
$   This_Dir  = F$PARSE(This_Dir,,,"DEVICE",) + F$PARSE(This_Dir,,,"DIRECTORY",)
$   This_File = F$ENVIRONMENT("PROCEDURE")
$   This_File = F$PARSE(This_File,,,"NAME",) + F$PARSE(This_File,,,"TYPE",)
$
$   UPD_HELP_INST_CNT  = 0
$   UPD_HELP_INST_LIST = ""
$
$   IF F$TRNLNM("VMI$KWD",,,,,) .EQS. ""
$   THEN
$   	In_Kit = FALSE
$	
$	IF P1 .EQS. ""
$       THEN
$           OPEN/READ UPD_HELP_TMP 'UPD_HELP_TMP_FILE'
$	    ASK_TMP := READ/END_OF_FILE= UPD_HELP_END_READ UPD_HELP_TMP
$
$	    UPD_HELP_START_READ:
$		ASK_TMP UPD_HELP_THIS_LINE
$		UPD_HELP_INST_LIST = UPD_HELP_INST_LIST + "\" + UPD_HELP_THIS_LINE
$		UPD_HELP_INST_CNT  = UPD_HELP_INST_CNT + 1
$		GOTO UPD_HELP_START_READ
$	    UPD_HELP_END_READ:
$
$	    CLOSE UPD_HELP_TMP
$       ENDIF
$	
$   ELSE
$   	In_Kit = TRUE
$	
$       IF P1 .EQS. ""
$       THEN
$   	    Say "  ''F$ENVIRONMENT("PROCEDURE")': The name of the .HLP file must be passed in P1."
$	    EXIT 0
$       ENDIF
$
$	UPD_HELP_INST_LIST = UPD_HELP_INST_LIST + "\" + P1
$	UPD_HELP_INST_CNT  = UPD_HELP_INST_CNT + 1
$
$   ENDIF
$
$   It_Worked = TRUE
$
$   NUM = 1
$   UPD_HELP_INST_LOOP:
$     IF It_Worked
$   	THEN
$         ON SEVERE_ERROR THEN It_Worked = FALSE
$         ON ERROR        THEN It_Worked = FALSE
$
$	  This_Help = F$ELEMENT(NUM,"\",UPD_HELP_INST_LIST)
$
$	  IF (This_Help .EQS. "\") .OR. (UPD_HELP_INST_LIST .EQS. "")
$         THEN
$             It_Worked = FALSE
$	      GOTO UPD_HELP_INST_LOOP
$         ENDIF
$
$	  IF In_Kit
$         THEN
$	      Hlp_File = F$SEARCH("VMI$KWD:''This_Help'")
$	      IF Hlp_File .EQS. ""
$	      THEN
$		Say " ''F$ENVIRONMENT("PROCEDURE")': Could not find the HELP file ''THIS_HELP' in VMI$KWD: to install."
$		EXIT 0
$	      ENDIF
$	      
$         ELSE
$	      Hlp_File = F$SEARCH("''This_Dir'''This_Help'")
$	      IF Hlp_File .EQS. ""
$	      THEN
$		 Say " Could not find the HELP file ''THIS_HELP' in ''This_Dir' to install."
$		 EXIT 0
$	      ENDIF
$	      
$         ENDIF
$         
$         LIBRARY/REPLACE SYS$HELP:HELPLIB.HLB 'Hlp_File'
$        
$          IF It_Worked
$          THEN
$            type sys$input
    
         DECevent help successfully inserted into the system
         help library.
    
$            IF In_Kit
$            THEN
$                VMI$CALLBACK    PROVIDE_FILE  HLP_     'THIS_HELP'         VMI$ROOT:[SYSHLP]
$                VMI$CALLBACK    SECURE_FILE   VMI$ROOT:[SYSHLP]'THIS_HELP'         [1,4] S:RWED,O:RED,G:RE,W:RE
$            ENDIF
$        ELSE
$	     type sys$input
    
         The system help library cannot be updated at this time.
         Please wait until no users are using the help facility
         and then re-run the SYS$HELP:DECEVENT$UPDATE_HELP.COM
         command file.
    
$           IF In_Kit
$           THEN
$               VMI$CALLBACK    PROVIDE_FILE  HLP_     'THIS_HELP'         VMI$ROOT:[SYSHLP]
$               VMI$CALLBACK    PROVIDE_FILE  HLP_     'This_File'  VMI$ROOT:[SYSHLP]
$               
$               VMI$CALLBACK    SECURE_FILE   VMI$ROOT:[SYSHLP]'THIS_HELP'         [1,4] S:RWED,O:RED,G:RE,W:RE
$               VMI$CALLBACK    SECURE_FILE   VMI$ROOT:[SYSHLP]'This_File'  [1,4] S:RWED,O:RED,G:RE,W:RE
$            
$               IF F$SEARCH(UPD_HELP_TMP_FILE) .EQS. "" THEN COPY NL: 'UPD_HELP_TMP_FILE'
$               OPEN/APPEND UPD_HELP_TMP 'UPD_HELP_TMP_FILE'
$               SAY_TMP := WRITE UPD_HELP_TMP
$               SAY_TMP THIS_HELP
$               CLOSE UPD_HELP_TMP
$           ENDIF
$         ENDIF
$	  NUM = NUM + 1
$   	  GOTO UPD_HELP_INST_LOOP
$     ENDIF
$
$   IF (NUM .GT. UPD_HELP_INST_CNT) .AND. (.NOT. In_Kit)
$   THEN
$   	IF F$SEARCH(UPD_HELP_TMP_FILE) .NES. "" THEN DELETE 'UPD_HELP_TMP_FILE';*
$!       DELETE 'F$ENVIRONMENT("PROCEDURE")'
$   ENDIF
$   
$   EXIT completion_code + 0*F$VERIFY(verify)