[0001]
[0002]
[0003]
[0004]
[0005]
[0006]
[0007]
[0008]
[0009]
[0010]
[0011]
[0012]
[0013]
[0014]
[0015]
[0016]
[0017]
[0018]
[0019]
[0020]
[0021]
[0022]
[0023]
[0024]
[0025]
[0026]
[0027]
[0028]
[0029]
[0030]
[0031]
[0032]
[0033]
[0034]
[0035]
[0036]
[0037]
[0038]
[0039]
[0040]
[0041]
[0042]
[0043]
[0044]
[0045]
[0046]
[0047]
[0048]
[0049]
[0050]
[0051]
[0052]
[0053]
[0054]
[0055]
[0056]
[0057]
[0058]
[0059]
[0060]
[0061]
[0062]
[0063]
[0064]
[0065]
[0066]
[0067]
[0068]
[0069]
[0070]
[0071]
[0072]
[0073]
[0074]
[0075]
[0076]

$!-----------------------------------------------------------------------------
$! WASD_FILE_DEV.COM
$!
$! If P1 is an integer between 2 and 15 sets up for that WASD environment.
$!
$! Logical name table may be deleted using (as appropriate)
$!
$!   DEASSIGN <table-name> /TABLE=LNM$<whichever>_DIRECTORY [/EXECUTIVE]
$!
$! as with
$!
$!   DEASSIGN WASD_TABLE /TABLE=LNM$SYSTEM_DIRECTORY [/EXECUTIVE]
$!   DEASSIGN WASD_TABLE /TABLE=LNM$PROCESS_DIRECTORY
$!
$! Copyright (C) 1996-2021 Mark G.Daniel.
$!
$! Licensed under the Apache License, Version 2.0 (the "License");
$! you may not use this file except in compliance with the License.
$! You may obtain a copy of the License at
$!
$!    http://www.apache.org/licenses/LICENSE-2.0
$!
$! Unless required by applicable law or agreed to in writing, software
$! distributed under the License is distributed on an "AS IS" BASIS,
$! WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
$! See the License for the specific language governing permissions and
$! limitations under the License.
$!
$! VERSION HISTORY
$! ---------------
$! 15-OCT-2010  MGD  check LNM$PROCESS_DIRECTORY to preserve structure
$!                     changes prior to running this procedure
$! 11-JUL-2009  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ if f$type(P1) .eqs. "INTEGER" .and. P1 .ge. 2
$ then
$    if P1 .gt. 15
$    then
$       write sys$output "%WASD_FILE_DEV-E-ENV, out-of-range"
$       exit %X10000014
$    endif
$    wasd_table = "WASD_TABLE_" + P1
$ else
$    wasd_table = "WASD_TABLE"
$ endif
$ if .not. f$trnlnm (wasd_table,"LNM$SYSTEM_DIRECTORY",0,"EXECUTIVE",,"TABLE")
$ then
$    write sys$output "%WASD_FILE_DEV-E-ENV, no such table"
$    exit %X10000014
$ endif
$ if f$trnlnm ("LNM$FILE_DEV","LNM$PROCESS_DIRECTORY") .nes. ""
$    then lnm_directory = "LNM$PROCESS_DIRECTORY"
$    else lnm_directory = "LNM$SYSTEM_DIRECTORY"
$ endif
$ index = 0
$ file_dev = ""
$ loop:
$    table = f$trnlnm ("LNM$FILE_DEV",lnm_directory,index)
$    if table .eqs. "" then goto loop_end
$    if table .nes. wasd_table
$    then
$       if file_dev .nes. "" then file_dev = file_dev + ","
$       file_dev = file_dev + table
$       if table .eqs. "LNM$JOB"
$       then
$           if file_dev .nes. "" then file_dev = file_dev + ","
$           file_dev = file_dev + wasd_table
$       endif
$    endif
$    index = index + 1
$    goto loop
$ loop_end:
$!
$ define /nolog /table=LNM$PROCESS_DIRECTORY LNM$FILE_DEV 'file_dev'
$!-----------------------------------------------------------------------------