[0001]
[0002]
[0003]
[0004]
[0005]
[0006]
[0007]
[0008]
[0009]
[0010]
[0011]
[0012]
[0013]
[0014]
[0015]
[0016]
[0017]
[0018]
[0019]
[0020]
[0021]
[0022]
[0023]
[0024]
[0025]
[0026]
[0027]
[0028]
[0029]
[0030]
[0031]
[0032]
[0033]
[0034]
[0035]
[0036]
[0037]
[0038]
[0039]
[0040]
[0041]
[0042]
[0043]
[0044]
[0045]
[0046]
[0047]
[0048]
[0049]
[0050]
[0051]
[0052]
[0053]
[0054]
[0055]
[0056]
[0057]
[0058]
[0059]
[0060]
[0061]
[0062]
[0063]
[0064]
[0065]
[0066]
[0067]
[0068]
[0069]
[0070]
[0071]
[0072]
[0073]
[0074]
[0075]
[0076]
[0077]
[0078]
[0079]
[0080]
[0081]
[0082]

$!-----------------------------------------------------------------'f$verify(0)
$! SCRIPTS_HTEXE_CGIBIN.COM
$!
$! Procedure to make ad hoc change of any HT_EXE: to CGI-BIN:[000000] in all
$! (script) procedures in [CGI-BIN], [AXP-BIN] and [VAX-BIN] or the directory
$! specified by P1.  Of use during the transition from pre-v8.1 to post-v8.1
$! package structure.
$!
$! 07-NOV-2009  MGD  disable for WASD v10
$! 13-DEC-2002  MGD  v1.0, initial
$!-----------------------------------------------------------------------------
$!
$ type sys$input

                  *****************************************
                  *   NOT INTENDED FOR WASD V10 OR LATER  *
                  *****************************************

If "upgrading" from pre-v8.1 then start from scratch and perform a completely
fresh installation!

$ exit 44
$!
$ ss$_abort = 44
$ ss$_bugcheck = 676
$ say = "write sys$output"
$!
$ if f$trnlnm("tmpf","lnm$process") .nes. "" then close tmpf
$ edt_cmd = "sys$scratch:install_scripts_all.tmp"
$ open /write tmpf 'edt_cmd'
$ write tmpf "SUBS \HT_EXE:\CGI-BIN:[000000]\ WH"
$ write tmpf "INSERT ;$!(MODIFIED BY SCRIPTS_HTEXE_CGIBIN.COM ''F$TIME()')"
$ write tmpf "INSERT ;$!(changed ""HT_EXE:"" to ""CGI-BIN:[000000]"")"
$ write tmpf "EX"
$ close tmpf
$ if p1 .eqs. ""
$ then
$    call edt_files "ht_root:[cgi-bin]*.com" "ht_exe:" 'edt_cmd'
$    call edt_files "ht_root:[axp-bin]*.com" "ht_exe:" 'edt_cmd'
$    call edt_files "ht_root:[vax-bin]*.com" "ht_exe:" 'edt_cmd'
$ else
$    call edt_files "''p1'*.COM" "ht_exe:" 'edt_cmd'
$ endif
$ delete /nolog /noconfirm sys$scratch:install_scripts_all.tmp;*
$ exit
$!
$!-----------------------------------------------------------------------------
$!
$ EDT_FILES: SUBROUTINE
$!
$! invoke EDIT/EDT to modify the specified file
$! P1 should contain a wildcard file specification
$! P2 the string used to identify the file as requiring editing
$! P3 the file containing the EDT editing commands
$!
$ on controly then exit ss$_abort
$ if p1 .eqs. "" then exit ss$_bugcheck
$ if p2 .eqs. "" then exit ss$_bugcheck
$ if p3 .eqs. "" then exit ss$_bugcheck
$ p1 = f$edit(p1,"upcase")
$ p2 = f$edit(p2,"upcase")
$ p3 = f$edit(p3,"upcase")
$ edit = "edit"
$ edt_files_loop:
$    file = f$search(p1)
$    if file .eqs. "" then goto end_edt_files_loop
$    define /user sys$error nl:
$    define /user sys$output nl:
$    search 'file' "''p2'"
$    if $severity .eq. 1
$    then
$       set noon
$       edit/edt/nojournal/command='p3' 'file'
$       set on
$    endif
$    goto edt_files_loop
$ end_edt_files_loop:
$!
$ exit
$ endsubroutine
$!
$!-----------------------------------------------------------------------------